configure: split out UML driver checks

Move all the UML driver related routines into m4/virt-driver-uml.m4.

diff --git a/configure.ac b/configure.ac
index 88e2e20845e6f2d4348ab60242eb79fcdb2fcf8e..d19c1a98664d3dc90fab645abf6e08ecea929ca2 100644 (file)
--- a/configure.ac
+++ b/configure.ac
@@ -537,10 +537,6 @@ AC_ARG_WITH([qemu],
   [AS_HELP_STRING([--with-qemu],
     [add QEMU/KVM support @<:@default=yes@:>@])])
 m4_divert_text([DEFAULTS], [with_qemu=yes])
-AC_ARG_WITH([uml],
-  [AS_HELP_STRING([--with-uml],
-    [add UML support @<:@default=check@:>@])])
-m4_divert_text([DEFAULTS], [with_uml=check])
 AC_ARG_WITH([openvz],
   [AS_HELP_STRING([--with-openvz],
     [add OpenVZ support @<:@default=check@:>@])])
@@ -1561,27 +1557,7 @@ dnl
 dnl Checks for the UML driver
 dnl
 
-if test "$with_libvirtd" = "no" ; then
-  with_uml=no
-fi
-if test "$with_uml" = "yes" || test "$with_uml" = "check"; then
-    AC_CHECK_HEADER([sys/inotify.h], [
-        with_uml=yes
-    ], [
-        if test "$with_uml" = "check"; then
-            with_uml=no
-            AC_MSG_NOTICE([<sys/inotify.h> is required for the UML driver, disabling it])
-        else
-            AC_MSG_ERROR([The <sys/inotify.h> is required for the UML driver. Upgrade your libc6.])
-        fi
-    ])
-fi
-if test "$with_uml" = "yes" ; then
-    AC_DEFINE_UNQUOTED([WITH_UML], 1, [whether UML driver is enabled])
-fi
-AM_CONDITIONAL([WITH_UML], [test "$with_uml" = "yes"])
-
-
+LIBVIRT_DRIVER_CHECK_UML
 
 dnl
 dnl check for PHYP
@@ -2747,7 +2723,7 @@ AC_MSG_NOTICE([Drivers])
 AC_MSG_NOTICE([])
 AC_MSG_NOTICE([      Xen: $with_xen])
 AC_MSG_NOTICE([     QEMU: $with_qemu])
-AC_MSG_NOTICE([      UML: $with_uml])
+LIBVIRT_DRIVER_RESULT_UML
 AC_MSG_NOTICE([   OpenVZ: $with_openvz])
 AC_MSG_NOTICE([   VMware: $with_vmware])
 AC_MSG_NOTICE([     VBox: $with_vbox])

diff --git a/m4/virt-driver-uml.m4 b/m4/virt-driver-uml.m4
new file mode 100644 (file)
index 0000000..811e4d1
--- /dev/null
+++ b/m4/virt-driver-uml.m4
@@ -0,0 +1,51 @@
+dnl The UML driver
+dnl
+dnl Copyright (C) 2005-2015 Red Hat, Inc.
+dnl
+dnl This library is free software; you can redistribute it and/or
+dnl modify it under the terms of the GNU Lesser General Public
+dnl License as published by the Free Software Foundation; either
+dnl version 2.1 of the License, or (at your option) any later version.
+dnl
+dnl This library is distributed in the hope that it will be useful,
+dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
+dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+dnl Lesser General Public License for more details.
+dnl
+dnl You should have received a copy of the GNU Lesser General Public
+dnl License along with this library.  If not, see
+dnl <http://www.gnu.org/licenses/>.
+dnl
+
+AC_DEFUN([LIBVIRT_DRIVER_CHECK_UML],[
+    AC_ARG_WITH([uml],
+      [AS_HELP_STRING([--with-uml],
+        [add UML support @<:@default=check@:>@])])
+    m4_divert_text([DEFAULTS], [with_uml=check])
+
+    if test "$with_libvirtd" = "no" ; then
+        with_uml=no
+    fi
+
+    if test "$with_uml" = "yes" || test "$with_uml" = "check"; then
+        AC_CHECK_HEADER([sys/inotify.h], [
+          with_uml=yes
+        ], [
+          if test "$with_uml" = "check"; then
+              with_uml=no
+              AC_MSG_NOTICE([<sys/inotify.h> is required for the UML driver, disabling it])
+          else
+              AC_MSG_ERROR([The <sys/inotify.h> is required for the UML driver. Upgrade your libc6.])
+          fi
+        ])
+    fi
+
+    if test "$with_uml" = "yes" ; then
+        AC_DEFINE_UNQUOTED([WITH_UML], 1, [whether UML driver is enabled])
+    fi
+    AM_CONDITIONAL([WITH_UML], [test "$with_uml" = "yes"])
+])
+
+AC_DEFUN([LIBVIRT_DRIVER_RESULT_UML],[
+    AC_MSG_NOTICE([      UML: $with_uml])
+])