ia64/xen-unstable

view linux-2.4.29-xen-sparse/arch/xen/vmlinux.lds @ 4146:f2d61710e4d9

bitkeeper revision 1.1236.25.24 (42366e9aQ71LQ8uCB-Y1IwVNqx5eqA)

Merge djm@kirby.fc.hp.com://home/djm/src/xen/xeno-unstable-ia64.bk
into sportsman.spdomain:/home/djm/xeno-unstable-ia64.bk
author djm@sportsman.spdomain
date Tue Mar 15 05:11:54 2005 +0000 (2005-03-15)
parents 0a4b76b6b5a0
children
line source
1 /* ld script to make i386 Linux kernel
2 * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>;
3 */
4 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
5 OUTPUT_ARCH(i386)
6 ENTRY(_start)
7 SECTIONS
8 {
9 . = 0xC0000000 + 0x100000;
10 _text = .; /* Text and read-only data */
11 .text : {
12 *(.text)
13 *(.fixup)
14 *(.gnu.warning)
15 } = 0x9090
17 _etext = .; /* End of text section */
19 .rodata : { *(.rodata) *(.rodata.*) }
20 .kstrtab : { *(.kstrtab) }
22 . = ALIGN(16); /* Exception table */
23 __start___ex_table = .;
24 __ex_table : { *(__ex_table) }
25 __stop___ex_table = .;
27 __start___ksymtab = .; /* Kernel symbol table */
28 __ksymtab : { *(__ksymtab) }
29 __stop___ksymtab = .;
31 .data : { /* Data */
32 *(.data)
33 CONSTRUCTORS
34 }
36 _edata = .; /* End of data section */
38 . = ALIGN(8192); /* init_task */
39 .data.init_task : { *(.data.init_task) }
41 . = ALIGN(4096); /* Init code and data */
42 __init_begin = .;
43 .text.init : { *(.text.init) }
44 .data.init : { *(.data.init) }
45 . = ALIGN(16);
46 __setup_start = .;
47 .setup.init : { *(.setup.init) }
48 __setup_end = .;
49 __initcall_start = .;
50 .initcall.init : { *(.initcall.init) }
51 __initcall_end = .;
52 . = ALIGN(4096);
53 __init_end = .;
55 . = ALIGN(4096);
56 .data.page_aligned : { *(.data.idt) }
58 . = ALIGN(32);
59 .data.cacheline_aligned : { *(.data.cacheline_aligned) }
61 __bss_start = .; /* BSS */
62 .bss : {
63 *(.bss)
64 }
65 _end = . ;
67 /* Stabs debugging sections. */
68 .stab 0 : { *(.stab) }
69 .stabstr 0 : { *(.stabstr) }
70 .stab.excl 0 : { *(.stab.excl) }
71 .stab.exclstr 0 : { *(.stab.exclstr) }
72 .stab.index 0 : { *(.stab.index) }
73 .stab.indexstr 0 : { *(.stab.indexstr) }
74 .comment 0 : { *(.comment) }
75 }