ia64/xen-unstable

view xen/arch/x86/x86_32/xen.lds.S @ 19835:edfdeb150f27

Fix buildsystem to detect udev > version 124

udev removed the udevinfo symlink from versions higher than 123 and
xen's build-system could not detect if udev is in place and has the
required version.

Signed-off-by: Marc-A. Dahlhaus <mad@wol.de>
author Keir Fraser <keir.fraser@citrix.com>
date Thu Jun 25 13:02:37 2009 +0100 (2009-06-25)
parents 3fc7d4115d6c
children
line source
1 /* ld script to make i386 Linux kernel
2 * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
3 * Modified for i386 Xen by Keir Fraser
4 */
6 #include <xen/config.h>
7 #include <asm/page.h>
8 #include <asm/percpu.h>
9 #undef ENTRY
10 #undef ALIGN
12 OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
13 OUTPUT_ARCH(i386)
14 ENTRY(start)
15 PHDRS
16 {
17 text PT_LOAD ;
18 }
19 SECTIONS
20 {
21 . = 0xFF000000 + 0x100000;
22 _start = .;
23 _stext = .; /* Text and read-only data */
24 .text : {
25 *(.text)
26 *(.fixup)
27 *(.gnu.warning)
28 } :text =0x9090
30 _etext = .; /* End of text section */
32 .rodata : { *(.rodata) *(.rodata.*) } :text
34 . = ALIGN(32); /* Exception table */
35 __start___ex_table = .;
36 __ex_table : { *(__ex_table) } :text
37 __stop___ex_table = .;
39 . = ALIGN(32); /* Pre-exception table */
40 __start___pre_ex_table = .;
41 __pre_ex_table : { *(__pre_ex_table) } :text
42 __stop___pre_ex_table = .;
44 .data : { /* Data */
45 *(.data)
46 CONSTRUCTORS
47 } :text
49 . = ALIGN(128);
50 .data.read_mostly : { *(.data.read_mostly) } :text
52 . = ALIGN(4096); /* Init code and data */
53 __init_begin = .;
54 _sinittext = .;
55 .init.text : { *(.init.text) } :text
56 _einittext = .;
57 .init.data : { *(.init.data) } :text
58 . = ALIGN(32);
59 __setup_start = .;
60 .init.setup : { *(.init.setup) } :text
61 __setup_end = .;
62 __initcall_start = .;
63 .initcall.init : { *(.initcall1.init) } :text
64 __initcall_end = .;
65 __xsm_initcall_start = .;
66 .xsm_initcall.init : { *(.xsm_initcall.init) } :text
67 __xsm_initcall_end = .;
68 . = ALIGN(PAGE_SIZE);
69 __init_end = .;
71 __per_cpu_shift = PERCPU_SHIFT; /* kdump assist */
72 __per_cpu_start = .;
73 .data.percpu : { *(.data.percpu) } :text
74 __per_cpu_data_end = .;
75 . = __per_cpu_start + (NR_CPUS << PERCPU_SHIFT);
76 . = ALIGN(PAGE_SIZE);
77 __per_cpu_end = .;
79 __bss_start = .; /* BSS */
80 .bss : {
81 . = ALIGN(STACK_SIZE);
82 *(.bss.stack_aligned)
83 . = ALIGN(PAGE_SIZE);
84 *(.bss.page_aligned)
85 *(.bss)
86 } :text
87 _end = . ;
89 /* Sections to be discarded */
90 /DISCARD/ : {
91 *(.exit.text)
92 *(.exit.data)
93 *(.exitcall.exit)
94 *(.eh_frame)
95 }
97 /* Stabs debugging sections. */
98 .stab 0 : { *(.stab) }
99 .stabstr 0 : { *(.stabstr) }
100 .stab.excl 0 : { *(.stab.excl) }
101 .stab.exclstr 0 : { *(.stab.exclstr) }
102 .stab.index 0 : { *(.stab.index) }
103 .stab.indexstr 0 : { *(.stab.indexstr) }
104 .comment 0 : { *(.comment) }
105 }