ia64/xen-unstable

view xen/arch/ia64/vmx/vmx_minstate.h @ 17369:6cf504b4de7d

[IA64] PAL virtualization services

- pal_vps_resume_handler: bit 63 of r26 is used to indicate whether
CFLE is set when resuming to guest
- Add sync_read and sync_write per spec.
- Use patching to reduce VPS call overhead

Signed-off-by: Anthony Xu <anthony.xu@intel.com>
author Alex Williamson <alex.williamson@hp.com>
date Mon Apr 14 13:59:45 2008 -0600 (2008-04-14)
parents 5ab3288e5b0f
children
line source
1 /*
2 * vmx_minstate.h:
3 * Copyright (c) 2005, Intel Corporation.
4 *
5 * This program is free software; you can redistribute it and/or modify it
6 * under the terms and conditions of the GNU General Public License,
7 * version 2, as published by the Free Software Foundation.
8 *
9 * This program is distributed in the hope it will be useful, but WITHOUT
10 * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
11 * FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for
12 * more details.
13 *
14 * You should have received a copy of the GNU General Public License along with
15 * this program; if not, write to the Free Software Foundation, Inc., 59 Temple
16 * Place - Suite 330, Boston, MA 02111-1307 USA.
17 *
18 * Xuefei Xu (Anthony Xu) (Anthony.xu@intel.com)
19 */
21 #include <linux/config.h>
23 #include <asm/asmmacro.h>
24 #include <asm/fpu.h>
25 #include <asm/mmu_context.h>
26 #include <asm/offsets.h>
27 #include <asm/pal.h>
28 #include <asm/pgtable.h>
29 #include <asm/processor.h>
30 #include <asm/ptrace.h>
31 #include <asm/system.h>
32 #include <asm/vmx_pal_vsa.h>
33 #include <asm/vmx_vpd.h>
34 #include <asm/cache.h>
35 #include "entry.h"
37 #define VMX_MINSTATE_START_SAVE_MIN \
38 (pUStk) mov ar.rsc=0; /* set enforced lazy mode, pl 0, little-endian, loadrs=0 */ \
39 ;; \
40 (pUStk) mov.m r28=ar.rnat; \
41 (pUStk) addl r22=IA64_RBS_OFFSET,r1; /* compute base of RBS */ \
42 (pKStk) mov r1=sp; /* get sp */ \
43 ;; \
44 (pUStk) lfetch.fault.excl.nt1 [r22]; \
45 (pUStk) addl r1=IA64_STK_OFFSET-IA64_PT_REGS_SIZE,r1; /* compute base of memory stack */ \
46 (pUStk) mov r23=ar.bspstore; /* save ar.bspstore */ \
47 ;; \
48 (pUStk) mov ar.bspstore=r22; /* switch to kernel RBS */ \
49 (pKStk) addl r1=-IA64_PT_REGS_SIZE,r1; /* if in kernel mode, use sp (r12) */ \
50 ;; \
51 (pUStk) mov r18=ar.bsp; \
52 (pUStk) mov ar.rsc=0x3; /* set eager mode, pl 0, little-endian, loadrs=0 */
54 #define VMX_MINSTATE_END_SAVE_MIN \
55 bsw.1; /* switch back to bank 1 (must be last in insn group) */ \
56 ;;
58 #define PAL_VSA_SYNC_READ \
59 /* begin to call pal vps sync_read */ \
60 { .mii; \
61 (pUStk) add r25=IA64_VPD_BASE_OFFSET, r21; \
62 (pUStk) nop 0x0; \
63 (pUStk) mov r24=ip; \
64 ;; \
65 }; \
66 { .mmb; \
67 (pUStk) add r24 = 0x20, r24; \
68 (pUStk) ld8 r25=[r25]; /* read vpd base */ \
69 (pUStk) br.cond.sptk vmx_vps_sync_read; /* call the service */ \
70 ;; \
71 };
73 #define IA64_CURRENT_REG IA64_KR(CURRENT) /* r21 is reserved for current pointer */
74 //#define VMX_MINSTATE_GET_CURRENT(reg) mov reg=IA64_CURRENT_REG
75 #define VMX_MINSTATE_GET_CURRENT(reg) mov reg=r21
77 /*
78 * VMX_DO_SAVE_MIN switches to the kernel stacks (if necessary) and saves
79 * the minimum state necessary that allows us to turn psr.ic back
80 * on.
81 *
82 * Assumed state upon entry:
83 * psr.ic: off
84 * r31: contains saved predicates (pr)
85 *
86 * Upon exit, the state is as follows:
87 * psr.ic: off
88 * r2 = points to &pt_regs.r16
89 * r8 = contents of ar.ccv
90 * r9 = contents of ar.csd
91 * r10 = contents of ar.ssd
92 * r11 = FPSR_DEFAULT
93 * r12 = kernel sp (kernel virtual address)
94 * r13 = points to current task_struct (kernel virtual address)
95 * p6 = (psr.vm || isr.ni)
96 * panic if not external interrupt (fault in xen VMM)
97 * p15 = TRUE if psr.i is set in cr.ipsr
98 * predicate registers (other than p2, p3, and p15), b6, r3, r14, r15:
99 * preserved
100 *
101 * Note that psr.ic is NOT turned on by this macro. This is so that
102 * we can pass interruption state as arguments to a handler.
103 */
105 #ifdef CONFIG_VMX_PANIC
106 # define P6_BR_VMX_PANIC (p6)br.spnt.few vmx_panic;
107 #else
108 # define P6_BR_VMX_PANIC /* nothing */
109 #endif
111 #define P6_BR_CALL_PANIC(panic_string) \
112 (p6) movl out0=panic_string; \
113 (p6) br.call.spnt.few b6=panic;
115 #define VMX_DO_SAVE_MIN(COVER,SAVE_IFS,EXTRA,VMX_PANIC) \
116 mov r27=ar.rsc; /* M */ \
117 mov r20=r1; /* A */ \
118 mov r25=ar.unat; /* M */ \
119 mov r29=cr.ipsr; /* M */ \
120 mov r26=ar.pfs; /* I */ \
121 mov r18=cr.isr; \
122 COVER; /* B;; (or nothing) */ \
123 ;; \
124 cmp.eq p6,p0=r0,r0; \
125 tbit.z pKStk,pUStk=r29,IA64_PSR_VM_BIT; \
126 tbit.z p0,p15=r29,IA64_PSR_I_BIT; \
127 ;; \
128 (pUStk) tbit.nz.and p6,p0=r18,IA64_ISR_NI_BIT; \
129 (pUStk)VMX_MINSTATE_GET_CURRENT(r1); \
130 VMX_PANIC \
131 /* switch from user to kernel RBS: */ \
132 ;; \
133 invala; /* M */ \
134 SAVE_IFS; \
135 ;; \
136 VMX_MINSTATE_START_SAVE_MIN \
137 adds r17=2*L1_CACHE_BYTES,r1; /* really: biggest cache-line size */ \
138 adds r16=PT(CR_IPSR),r1; \
139 ;; \
140 lfetch.fault.excl.nt1 [r17],L1_CACHE_BYTES; \
141 st8 [r16]=r29; /* save cr.ipsr */ \
142 ;; \
143 lfetch.fault.excl.nt1 [r17]; \
144 mov r29=b0 \
145 ;; \
146 adds r16=PT(R8),r1; /* initialize first base pointer */ \
147 adds r17=PT(R9),r1; /* initialize second base pointer */ \
148 (pKStk) mov r18=r0; /* make sure r18 isn't NaT */ \
149 ;; \
150 .mem.offset 0,0; st8.spill [r16]=r8,16; \
151 .mem.offset 8,0; st8.spill [r17]=r9,16; \
152 ;; \
153 .mem.offset 0,0; st8.spill [r16]=r10,24; \
154 .mem.offset 8,0; st8.spill [r17]=r11,24; \
155 ;; \
156 mov r9=cr.iip; /* M */ \
157 mov r10=ar.fpsr; /* M */ \
158 ;; \
159 st8 [r16]=r9,16; /* save cr.iip */ \
160 st8 [r17]=r30,16; /* save cr.ifs */ \
161 (pUStk) sub r18=r18,r22;/* r18=RSE.ndirty*8 */ \
162 ;; \
163 st8 [r16]=r25,16; /* save ar.unat */ \
164 st8 [r17]=r26,16; /* save ar.pfs */ \
165 shl r18=r18,16; /* compute ar.rsc to be used for "loadrs" */ \
166 ;; \
167 st8 [r16]=r27,16; /* save ar.rsc */ \
168 (pUStk) st8 [r17]=r28,16;/* save ar.rnat */ \
169 (pKStk) adds r17=16,r17;/* skip over ar_rnat field */ \
170 ;; /* avoid RAW on r16 & r17 */ \
171 (pUStk) st8 [r16]=r23,16; /* save ar.bspstore */ \
172 st8 [r17]=r31,16; /* save predicates */ \
173 (pKStk) adds r16=16,r16; /* skip over ar_bspstore field */ \
174 ;; \
175 st8 [r16]=r29,16; /* save b0 */ \
176 st8 [r17]=r18,16; /* save ar.rsc value for "loadrs" */ \
177 cmp.eq pNonSys,pSys=r0,r0 /* initialize pSys=0, pNonSys=1 */ \
178 ;; \
179 .mem.offset 0,0; st8.spill [r16]=r20,16; /* save original r1 */ \
180 .mem.offset 8,0; st8.spill [r17]=r12,16; \
181 adds r12=-16,r1; /* switch to kernel memory stack (with 16 bytes of scratch) */ \
182 ;; \
183 .mem.offset 0,0; st8.spill [r16]=r13,16; \
184 .mem.offset 8,0; st8.spill [r17]=r10,16; /* save ar.fpsr */ \
185 (pUStk) VMX_MINSTATE_GET_CURRENT(r13); /* establish `current' */ \
186 (pKStk) movl r13=THIS_CPU(cpu_kr)+IA64_KR_CURRENT_OFFSET;/* From MINSTATE_GET_CURRENT */\
187 ;; \
188 .mem.offset 0,0; st8.spill [r16]=r15,16; \
189 .mem.offset 8,0; st8.spill [r17]=r14,16; \
190 (pKStk) ld8 r13=[r13]; /* establish `current' */ \
191 ;; \
192 .mem.offset 0,0; st8.spill [r16]=r2,16; \
193 .mem.offset 8,0; st8.spill [r17]=r3,16; \
194 adds r2=IA64_PT_REGS_R16_OFFSET,r1; \
195 ;; \
196 (pUStk) adds r16=IA64_VCPU_IIPA_OFFSET,r13; \
197 (pUStk) adds r17=IA64_VCPU_ISR_OFFSET,r13; \
198 (pUStk) mov r26=cr.iipa; \
199 (pUStk) mov r27=cr.isr; \
200 ;; \
201 (pUStk) st8 [r16]=r26; \
202 (pUStk) st8 [r17]=r27; \
203 ;; \
204 EXTRA; \
205 mov r8=ar.ccv; \
206 mov r9=ar.csd; \
207 mov r10=ar.ssd; \
208 movl r11=FPSR_DEFAULT; /* L-unit */ \
209 movl r1=__gp; /* establish kernel global pointer */ \
210 ;; \
211 PAL_VSA_SYNC_READ \
212 VMX_MINSTATE_END_SAVE_MIN
214 /*
215 * SAVE_REST saves the remainder of pt_regs (with psr.ic on).
216 *
217 * Assumed state upon entry:
218 * psr.ic: on
219 * r2: points to &pt_regs.f6
220 * r3: points to &pt_regs.f7
221 * r8: contents of ar.ccv
222 * r9: contents of ar.csd
223 * r10: contents of ar.ssd
224 * r11: FPSR_DEFAULT
225 *
226 * Registers r14 and r15 are guaranteed not to be touched by SAVE_REST.
227 */
228 #define VMX_SAVE_REST \
229 .mem.offset 0,0; st8.spill [r2]=r16,16; \
230 .mem.offset 8,0; st8.spill [r3]=r17,16; \
231 ;; \
232 .mem.offset 0,0; st8.spill [r2]=r18,16; \
233 .mem.offset 8,0; st8.spill [r3]=r19,16; \
234 ;; \
235 .mem.offset 0,0; st8.spill [r2]=r20,16; \
236 .mem.offset 8,0; st8.spill [r3]=r21,16; \
237 mov r18=b6; \
238 ;; \
239 .mem.offset 0,0; st8.spill [r2]=r22,16; \
240 .mem.offset 8,0; st8.spill [r3]=r23,16; \
241 mov r19=b7; \
242 ;; \
243 .mem.offset 0,0; st8.spill [r2]=r24,16; \
244 .mem.offset 8,0; st8.spill [r3]=r25,16; \
245 ;; \
246 .mem.offset 0,0; st8.spill [r2]=r26,16; \
247 .mem.offset 8,0; st8.spill [r3]=r27,16; \
248 ;; \
249 .mem.offset 0,0; st8.spill [r2]=r28,16; \
250 .mem.offset 8,0; st8.spill [r3]=r29,16; \
251 ;; \
252 .mem.offset 0,0; st8.spill [r2]=r30,16; \
253 .mem.offset 8,0; st8.spill [r3]=r31,32; \
254 ;; \
255 mov ar.fpsr=r11; \
256 st8 [r2]=r8,8; \
257 adds r24=PT(B6)-PT(F7),r3; \
258 ;; \
259 stf.spill [r2]=f6,32; \
260 stf.spill [r3]=f7,32; \
261 ;; \
262 stf.spill [r2]=f8,32; \
263 stf.spill [r3]=f9,32; \
264 ;; \
265 stf.spill [r2]=f10,32; \
266 stf.spill [r3]=f11; \
267 adds r25=PT(B7)-PT(F11),r3; \
268 ;; \
269 st8 [r24]=r18,16; /* b6 */ \
270 st8 [r25]=r19,16; /* b7 */ \
271 adds r3=PT(R5)-PT(F11),r3; \
272 ;; \
273 st8 [r24]=r9; /* ar.csd */ \
274 st8 [r25]=r10; /* ar.ssd */ \
275 ;; \
276 (pUStk)mov r18=ar.unat; \
277 (pUStk)adds r19=PT(EML_UNAT)-PT(R4),r2; \
278 ;; \
279 (pUStk)st8 [r19]=r18; /* eml_unat */
281 #define VMX_SAVE_EXTRA \
282 .mem.offset 0,0; st8.spill [r2]=r4,16; \
283 .mem.offset 8,0; st8.spill [r3]=r5,16; \
284 ;; \
285 .mem.offset 0,0; st8.spill [r2]=r6,16; \
286 .mem.offset 8,0; st8.spill [r3]=r7; \
287 ;; \
288 mov r26=ar.unat; \
289 ;; \
290 st8 [r2]=r26; /* eml_unat */
292 #define VMX_SAVE_MIN_WITH_COVER VMX_DO_SAVE_MIN(cover, mov r30=cr.ifs,, P6_BR_VMX_PANIC)
293 #define VMX_SAVE_MIN_WITH_COVER_NO_PANIC \
294 VMX_DO_SAVE_MIN(cover, mov r30=cr.ifs,, )
295 #define VMX_SAVE_MIN_WITH_COVER_R19 VMX_DO_SAVE_MIN(cover, mov r30=cr.ifs, mov r15=r19, P6_BR_VMX_PANIC)
296 #define VMX_SAVE_MIN VMX_DO_SAVE_MIN( , mov r30=r0,, P6_BR_VMX_PANIC)
298 /*
299 * Local variables:
300 * mode: C
301 * c-set-style: "BSD"
302 * c-basic-offset: 4
303 * tab-width: 4
304 * indent-tabs-mode: nil
305 * End:
306 */