ia64/linux-2.6.18-xen.hg

view arch/cris/arch-v10/vmlinux.lds.S @ 673:3161879fdf22

[IA64] xencomm: support XENMEM_add_to_physmap and XENMEM_remove_from_phsymap

support XENMEM_add_to_physmap and XENMEM_remove_from_phsymap.

Signed-off-by: Isaku Yamahata <yamahata@valinux.co.jp>
author Isaku Yamahata <yamahata@valinux.co.jp>
date Tue Sep 16 21:26:15 2008 +0900 (2008-09-16)
parents 831230e53067
children
line source
1 /* ld script to make the Linux/CRIS kernel
2 * Authors: Bjorn Wesen (bjornw@axis.com)
3 *
4 * It is VERY DANGEROUS to fiddle around with the symbols in this
5 * script. It is for example quite vital that all generated sections
6 * that are used are actually named here, otherwise the linker will
7 * put them at the end, where the init stuff is which is FREED after
8 * the kernel has booted.
9 */
11 #include <asm-generic/vmlinux.lds.h>
13 jiffies = jiffies_64;
14 SECTIONS
15 {
16 . = DRAM_VIRTUAL_BASE;
17 dram_start = .;
18 ibr_start = .;
19 . = . + 0x4000; /* see head.S and pages reserved at the start */
21 _text = .; /* Text and read-only data */
22 text_start = .; /* lots of aliases */
23 _stext = .;
24 __stext = .;
25 .text : {
26 *(.text)
27 SCHED_TEXT
28 LOCK_TEXT
29 *(.fixup)
30 *(.text.__*)
31 }
33 _etext = . ; /* End of text section */
34 __etext = .;
36 . = ALIGN(4); /* Exception table */
37 __start___ex_table = .;
38 __ex_table : { *(__ex_table) }
39 __stop___ex_table = .;
41 RODATA
43 . = ALIGN (4);
44 ___data_start = . ;
45 __Sdata = . ;
46 .data : { /* Data */
47 *(.data)
48 }
49 __edata = . ; /* End of data section */
50 _edata = . ;
52 . = ALIGN(8192); /* init_task and stack, must be aligned */
53 .data.init_task : { *(.data.init_task) }
55 . = ALIGN(8192); /* Init code and data */
56 __init_begin = .;
57 .init.text : {
58 _sinittext = .;
59 *(.init.text)
60 _einittext = .;
61 }
62 .init.data : { *(.init.data) }
63 . = ALIGN(16);
64 __setup_start = .;
65 .init.setup : { *(.init.setup) }
66 __setup_end = .;
67 .initcall.init : {
68 __initcall_start = .;
69 *(.initcall1.init);
70 *(.initcall2.init);
71 *(.initcall3.init);
72 *(.initcall4.init);
73 *(.initcall5.init);
74 *(.initcall6.init);
75 *(.initcall7.init);
76 __initcall_end = .;
77 }
79 .con_initcall.init : {
80 __con_initcall_start = .;
81 *(.con_initcall.init)
82 __con_initcall_end = .;
83 }
84 SECURITY_INIT
86 .init.ramfs : {
87 __initramfs_start = .;
88 *(.init.ramfs)
89 __initramfs_end = .;
90 /* We fill to the next page, so we can discard all init
91 pages without needing to consider what payload might be
92 appended to the kernel image. */
93 FILL (0);
94 . = ALIGN (8192);
95 }
97 __vmlinux_end = .; /* last address of the physical file */
98 __init_end = .;
100 __data_end = . ; /* Move to _edata ? */
101 __bss_start = .; /* BSS */
102 .bss : {
103 *(COMMON)
104 *(.bss)
105 }
107 . = ALIGN (0x20);
108 _end = .;
109 __end = .;
111 /* Sections to be discarded */
112 /DISCARD/ : {
113 *(.text.exit)
114 *(.data.exit)
115 *(.exitcall.exit)
116 }
118 dram_end = dram_start + CONFIG_ETRAX_DRAM_SIZE*1024*1024;
119 }